PROGRAMME DE CALCUL DE MAREES POUR CALCULATRICE PROGRAMMABLE HEWLETT-PACKARD HP 48 G

Un appui sur la touche CST permet d’afficher le menu suivant :


 

Rappel :  Les touches de fonction sont référencées A,B,C,D,E et F
Ainsi INIT=A, CALE(ndrier)=B,etc...
 


La touche A permet de lancer la fonction INIT . à lancement du calcul de la table des marées pour un port un jour donné.
 
 

Sélectionner le port à l’aide des flèches haut et

bas puis presser sur F pour valider (touche OK).


 
 

Sélectionner la date courante , le lendemain ou autre par les flèches haut et bas puis OK

(touche F) .

Si l’on a choisi une autre date : entrer celle-ci sous la forme : JJ.MMAAAA c’est-à-dire

Exemple ici : 18 août 1998

Faire ENTER.
 
 

Entrer le décalage horaire en France. Les heures sont données en heures locales.

Pour les ports français : heure TU + 1h + le décalage été/hiver soit TU + 2 en été.
Pour les ports anglais : heure TU + le décalage été/hiver soit TU + 1 en été. (heure BST = British Summer Time).

 
Après une vingtaine de secondes de calcul le calendrier ci-dessus s’affiche avec les heures et hauteurs des pleines (PL M) et basses (BS M) mers. On peut rappeler à tout moment ce dernier par la touche B (CALE). Il correspond au dernier calcul lancé par INIT.

La touche C (CALHT) permet de calculer la hauteur d’eau à n’importe quel moment de la journée pour le port et la date initialisés.

Entrer les heures et minutes (ex : 18 h 02 mn) sous le format HH.MM puis appuyer sur ENTER.

Le résultat s’affiche après quelques secondes. Pour revenir au menu appuyer sur F (OK).


 
 

Un appui sur D (TPREEL) permet de calculer la hauteur d’eau à l’instant présent pourvu que

le calcul ait été fait pour la date actuelle sinon un message d’erreur apparaît :
 
 

Il faut alors relancer le calcul par INIT (après avoir validé le message par OK - touche F) et choisir comme date : AUJOURD’HUI.
 
 

Listings des programmes :   (disponible sur demande le pack chargeable par RS232 en protocole Kermit pour les possesseurs du kit de connexion au PC)

 Les modules se trouvent dans un répertoire RMAREES , sous-répertoire de HOME.

 Le module d’initialisation effectue le calcul des seize constantes pour le port et la date choisis.
 Il affiche la table horaire des marées pour la journée en appelant le module CALEN.
 Il est découpé en cinq modules pour faciliter l’édition et les éventuelles modifications ainsi que le
 transfert  PC vers calculatrice via la liaison série.

 On trouvera donc ci-après :
 Le module INIT  (avec INI2, INI3, INI4, INI5).
 
 

 Les modules :
 

Les sous-programmes utilisés par les différents modules ( voir ci-après)
 
 
 
INIT.

@ Calcul de marées
 

« "_" 'J' STO
"_" 'MES1' STO
"_" 'MES2' STO
"_" 'MES3' STO
"_" 'MES4' STO 
« "CHOIX DU PORT" {                         @ INIT du PORT et de la DATE
{ "DUNKERQUE" 1 }
{"CHERBOURG" 2 }
{"BREST" 3 }
{"SHOREHAM" 4}
{"CALAIS *" 5}
{"DOVER *" 6}
{"BOULOGNE" 7}
{"PORTSMOUTH **" 8}
{"SOUTHAMPTON ***" 9}
{"DIEPPE" 10}
} 1
CHOOSE                                                 @ INIT des harmoniques sur la pile
  IF 1 ==
  THEN ® X
    «
      CASE
        X 1 == THEN DK END
        X 2 == THEN CH END
        X 3 == THEN BR END
        X 4 == THEN SH END
        X 5 == THEN CA END
        X 6 == THEN DV END
        X 7 == THEN BO END
        X 8 == THEN PO END
        X 9 == THEN SO END
        X 10 == THEN DI END
      END
    »
  END DROP 'MS4.G'
STO 'MS4.A' STO
'M4.G' STO 'M4.A'
STO 'MN4.G' STO
'MN4.A' STO 'S2.G'
STO 'S2.A' STO
'M2.G' STO 'M2.A'
STO 'N2.G' STO
'N2.A' STO 'K1.G'
STO 'K1.A' STO
'O1.G' STO 'O1.A'
STO 'Q1.G' STO
'Q1.A' STO 'SA.G'
STO 'SA.A' STO 'Z0'
STO
6 FIX
"Choisir la date" {
{ "Aujourd'hui" 1 }
{ "Demain" 2 } {
"Autre" 3 } } 1
CHOOSE
  IF 1 ==
  THEN ® X
    «
      CASE X 1 ==
        THEN DATE
        END
        X 2 ==
        THEN DATE 1
        DATE+
        END
        X 3 ==
        THEN

"Entrer la date :"
"" INPUT OBJ®
        END
      END
    »
  END
  DUP
  'DTE' STO                                          @ sauvegarde de la date
  EXTDATE
2 FIX
"Decalage horaire"
{ { "été" 1 } {
"hiver" 0 } } 1
CHOOSE
  IF 1 ==
  THEN 'DECAL' STO
  END
CALCT                                     @ T = nbre de jours depuis le 1/1/1980
CLEAR
PORT
EPHE                                         @ calcul des éphémérides à 0 h et 24 h.
INI2
INI3
INI4
INI5
»
 
 

INI2

«
0 'X0' STO                                   @ Init des sommes vectorielles pour 0 et 24h ondes diurnes
0 'Y0' STO
0 'X24' STO
0 'Y24' STO

90 H0 - 'VIJ' STO
K1.A -3 / 'AM' STO                    @ onde diurne P1
K1.G 'PH' STO
XY1                                             @ somme pour 0 h
450 H24 - 'VIJ' STO                    @ 15*24+90-H
XY2                                             @ somme pour 24 h
 

2 NEG S0 * H0 + N0 - 90 - 'VIJ' STO
O1.A 5.3 / 'AM' STO                   @ correction nodale de O1}
O1.G 'PH' STO
XY1
270 2 S24 * - H24 + N24 - 'VIJ' STO   @ valeur à 0h + 15 * 24}
XY2
 

H0 N0 + 90 + 'VIJ' STO
K1.A 7.4 / 'AM' STO                             @ correction nodale de K1}
K1.G 'PH' STO
XY1
450 H24 + N24 +  'VIJ' STO                 @ valeur à 0h + 15 * 24}
XY2
 

H0 90 + 'VIJ' STO
K1.A 'AM' STO                                       @ onde diurne K1}
XY1
450 H24 +  'VIJ' STO                              @ valeur à 0h + 15 * 24}
XY2
 

-2 S0 * H0 + 90 - 'VIJ' STO
O1.A 'AM' STO                                      @ onde diurne O1}
O1.G 'PH' STO
XY1
270 2 S24 * - H24 + 'VIJ' STO               @ valeur à 0h + 15 * 24}
XY2
 

-3 S0 * H0 + P0 + 90 - 'VIJ' STO
Q1.A 'AM' STO                                      @ onde diurne Q1}
Q1.G 'PH' STO
XY1
270 3 S24 * - H24 + P24 + 'VIJ' STO    @ valeur à 0h + 15 * 24}
XY2

X0 Y0 MODARG 'E' STO                      @ E = argument}
'D' STO                                                   @ D = module }
X24 Y24 MODARG 'G' STO                 @ F =}
'F' STO                                                   @ G =}
'G' E STO-
IF 'G<-180' THEN 'G' 360 STO+ END
IF 'G>180' THEN 'G' 360 STO- END
»
 

INI3

«
0 'X0' STO                               @ Init de la somme pour l'onde annuelle
0 'Y0' STO
0 'X24' STO
0 'Y24' STO

H0 'VIJ' STO
SA.A 'AM' STO                       @ onde SA
SA.G 'PH' STO
XY1                                         @ somme pour 0 h
H24 'VIJ' STO
XY2                                         @ somme pour 24 h

X0 Y0 MODARG 'C' STO            @ B =}
'B' STO                                          @ C =}
X24 Y24 MODARG 'K' STO        @ I =}
'I' STO                                           @ K =}
'K' C STO-
IF 'K<-180' THEN 'K' 360 STO+ END
IF 'K>180' THEN 'K' 360 STO- END
 

0 'X0' STO                                         @ Init des vecteurs semi-diurnes
0 'Y0' STO
0 'X24' STO
0 'Y24' STO

2 H0 * 2 S0 * - 'VIJ' STO
M2.A 'AM' STO                                 @ onde semi-diurne M2
M2.G 'PH' STO
XY1                                                    @ somme pour 0 h
720 2 S24  * - 2 H24 * + 'VIJ' STO
XY2                                                    @ somme pour 24 h

2 H0 * S0 - P0 - 'VIJ' STO
M2.A -35 / 'AM' STO                         @ onde semi-diurne L2 tir‚e de M2
XY1                                                    @ somme pour 0 h
720 S24 - 2 H24 * + P24 - 'VIJ' STO
XY2                                                    @ somme pour 24 h
 

2 H0 * 2 S0 * - N0 - 'VIJ' STO
M2.A -27 / 'AM' STO                        @ correction nodale de M2
XY1                                                   @ somme pour 0 h
720 2 S24  * - 2 H24 * + N24 - 'VIJ' STO
XY2                                                   @ somme pour 24 h
 
 

2 H0 * S0 3 * - P0 + 'VIJ' STO
N2.A 'AM' STO                                 @ onde semi-diurne N2
N2.G 'PH' STO
XY1                                                   @ somme pour 0 h
720 S24 3 * - 2 H24 * + P24 + 'VIJ' STO
XY2                                                   @ somme pour 24 h
»
 

INI4

«

2 H0 * S0 4 * - P0 2 * + 'VIJ' STO
N2.A 7.6 / 'AM' STO                                     @ onde semi-diurne 2N2
XY1                                                                @ somme pour 0 h
720 S24 2 * H24 - P24 - 2 * - 'VIJ' STO
XY2                                                                @ somme pour 24 h
 

4 H0 * S0 4 * - 'VIJ' STO
N2.A 6.3 / 'AM' STO                                      @ onde semi-diurne mu2
XY1                                                                 @ somme pour 0 h
720 S24 4 * - 4 H24 * +  'VIJ' STO
XY2                                                                 @ somme pour 24 h
 

4 H0 * S0 3 * - P0 - 'VIJ' STO
N2.A 5.3 / 'AM' STO                                        @ onde semi-diurne v2
XY1                                                                   @ somme pour 0 h
720 S24 3 * - H24 4 * + P24 -  'VIJ' STO
XY2                                                                  @ somme pour 24 h

0 'VIJ' STO
S2.A 'AM' STO                                                 @ onde semi-diurne S2
S2.G 'PH' STO
XY1                                                                   @ somme pour 0 h
720 'VIJ' STO
XY2                                                                   @ somme pour 24 h
 

2 H0 * 'VIJ' STO
S2.A 3.7 / 'AM' STO                                          @ onde semi-diurne K2
XY1                                                                   @ somme pour 0 h
720 H24 2 * + 'VIJ' STO
XY2                                                                   @ somme pour 24 h
 

2 H0 * N0 + 'VIJ' STO
S2.A 12 / 'AM' STO                                           @ correction nodale de K2
XY1                                                                    @ somme pour 0 h
720 H24 2 * + N24 +  'VIJ' STO
XY2                                                                    @ somme pour 24 h
 

H0 NEG 'VIJ' STO
S2.A 17 / 'AM' STO                                           @ onde semi-diurne T2
S2.G 283 - 'PH' STO
XY1                                                                   @ somme pour 0 h
720 H24 -  'VIJ' STO
XY2                                                                   @ somme pour 24 h
X0 Y0 MODARG 'R' STO                                @ Q =}
'Q' STO                                                             @ R =}
X24 Y24 MODARG 'W' STO                           @ U =}
'U' STO                                                             @ W =}
'W' R STO-
IF 'W<-180' THEN 'W' 360 STO+ END
IF 'W>180' THEN 'W' 360 STO- END
»
 
 

INI5

«
0 'X0' STO                                                       @ Init des sommes quart-diurnes
0 'Y0' STO
0 'X24' STO
0 'Y24' STO
 

4 H0 * 5 S0 * - P0 + 'VIJ' STO
MN4.A 'AM' STO                                           @ onde quart-diurne MN4
MN4.G 'PH' STO
XY1                                                                 @ somme pour 0 h
1440 5 S24 * - 4 H24 * + P24 + 'VIJ' STO
XY2                                                                 @ somme pour 24 h
 

4 H0 * 4 S0 * - 'VIJ' STO
M4.A 'AM' STO                                              @ onde quart-diurne M4
M4.G 'PH' STO
XY1                                                                @ somme pour 0 h
1440 4 S24 * - 4 H24 * + 'VIJ' STO
XY2                                                                @ somme pour 24 h
 

2 H0 * 2 S0 * - 'VIJ' STO
MS4.A 'AM' STO                                          @ onde quart-diurne MS4
MS4.G 'PH' STO
XY1                                                               @ somme pour 0 h
1440 2 S24 * - 2 H24 * + 'VIJ' STO
XY2                                                               @ somme pour 24 h

X0 Y0 MODARG 'Z2' STO                          @ Z1=}
'Z1' STO                                                        @ Z2=}
X24 Y24 MODARG 'Z4' STO                      @ Z3=}
'Z3' STO                                                        @ Z4=}
'Z4' Z2 STO-
IF 'Z4<-180' THEN 'Z4' 360 STO+ END
IF 'Z4>180' THEN 'Z4' 360 STO- END

CLEAR                                                          @ efface la pile
'I' B STO-                                                      @ I = dR0
'F' D STO-                                                     @ F = dR1
'G' 360 STO+
'U' Q STO-
'W' 720 STO+
'Z3' Z1 STO-
'Z4' 1440 STO+
D F 2 / + 'Z7' STO                                        @ Z[7] = : R1 à midi pour tester le type de marée.

Q U 2 / + 'Z8' STO                                       @ Z[8] = : R2 à midi
2 'J' STO                                                       @ on pose la marée semi-diurne
IF 'Z8<0.25*Z7' THEN
     1 'J' STO                                                  @ ce n’est pas le cas : marée diurne
     E 'Z7' STO                                               @ Z[7] =.Calcul approché à partir des ondes diurnes
G 'Z8' STO                                                    @ Z[8] =}

 ELSE
 R 'Z7' STO                                                   @ marée semi-diurne : j = 2}
                                                                      @ Z[7] =}
 W 'Z8' STO
 END
 Z7 'V' STO  CORRAG                                 @ recadre l'angle entre -180  et +180
 V 'Z7' STO
 Z8 'V' STO  CORRAG
 V 'Z8' STO
J 360 * Z8 + 'L' STO                                    @ L = variable intermédiaire
24 180 * L / 'S' STO                                     @ valeur approchée de la durée moyenne de la marée
0 'M' STO                                                     @ M = 0 si marée descendante
IF 'Z7<0' THEN
                                                                     @"Marée MONTANTE"
-24 Z7 * L / 'Z8' STO                                   @ Z8 est l'heure approchée de la marée haute
@"PLEINE MER"
APN
T Y FMTTH
"PL M." SWAP + DUP 'MES1' STO
APN
T Y FMTTH
"BS M." SWAP + DUP 'MES2' STO
APN
T Y FMTTH
"PL M." SWAP + DUP 'MES3' STO
APN
T Y FMTTH
"BS M." SWAP + DUP 'MES4' STO
 

ELSE
180 Z7 - L / 24 * 'Z8' STO                          @ Z[8] est l'heure approchée de la marée basse
                                                                    @"Marée DESCENDANTE"
APN
T Y FMTTH
"BS M." SWAP + DUP 'MES1' STO
APN
T Y FMTTH
"PL M." SWAP + DUP 'MES2' STO
APN
T Y FMTTH
"BS M." SWAP + DUP 'MES3' STO
APN
T Y FMTTH
"PL M." SWAP + DUP 'MES4' STO
END
CALEN                                                    @ affiche le calendrier pour
                                                                 @ la journée.
»
 

CALEN

@Calendrier
 « PORT CLLCD 1 DISP                       @ affiche le nom du port
"Le " 6 FIX DTE                                     @ la date
®STR 2 FIX
+ 2 DISP
MES1 3 DISP                                        @ heure et hauteur d’eau
MES2 4 DISP
MES3 5 DISP
MES4 6 DISP
7 FREEZE
»
 
 
 

CALHT

 « CLEAR PORT
"Hauteur d´eau"
" :HEURE:" INPUT
DUP 'HR' STO                                    @ sauve l'heure "HMS" dans HR
OBJ®                                                 @ HMS sur la pile
HMS® 'T' STO                                  @ heure décimale dans T
HR CHT AFFTH                                 @ appelle le ss prog CHT  (calcul hauteur)
                                                            @ et AFFTH ( affiche heure et hauteur ).
»

TPREEL

 « PORT DATE DUP DTE                  @ vérifie si la date actuelle est celle enregistrée
  IF SAME
  THEN TIME HMS® 'T' STO
  CHT AFFTH
  ELSE PORT "
  La date ne correspond pas" +
  MSGBOX
  END
»
 

SOUS-PROGRAMMES :

Les données des ports sont les harmoniques sauvegardées dans les fichiers XXHARM , XX identifiant
Le port.

Exemple pour Dunkerque :

DKHARM

{ 3.24 .07 233 .032
111 .086 177 .033
12 .372 357 2.116
22 .627 75 .057 310
.156 337 .087 35 }

Les harmoniques sont chargées dans la pile par le ss-prog DK

DK
 « DKHARM OBJ®
"Dunkerque " 'PORT'
STO
»

EXTDATE                                                  @ Extraction des éléments de la date.

 « DUP DUP IP 'J'                                        @ initialise J,M et A … partir de JJ,MMAAAA
STO FP 100 * IP 'M'
STO 100 * FP 10000
* 'A' STO
»
 
 
 

CALCT

 « 1 M 1 + / .7 + IP                                     @ Calcul de T : nbre de jours écoulés depuis le 1/1/1980
12 * M + 1 +
30.6001 * IP 1 M 1
+ / .7 + IP NEG A +
365.25 * IP + J +
-723258 + 'T' STO
»
 

EPHE       @ Calcul des éléments astro pour 0h et 24h.

«
                                                                    @ à 0 H.
78.16  13.17639673 T * + 'S0' STO           @ longitude moyenne de la lune
279.82  0.98564734 T * + 'H0' STO          @ longitude moyenne du soleil
349.50  0.11140408 T * + 'P0' STO           @ longitude du périgée de la lune
208.10  0.05295392 T * + 'N0' STO          @ - longitude du noeud ascendant de la lune

                             @ à 24 H.
T 1 + 'T' STO
78.16  13.17639673 T * + 'S24' STO         @ longitude moyenne de la lune
279.82  0.98564734 T * + 'H24' STO        @ longitude moyenne du soleil
349.50  0.11140408 T * + 'P24' STO         @ longitude du périgée de la lune
208.10  0.05295392 T * + 'N24' STO        @ - longitude du noeud ascendant de la lune
T 1 - 'T' STO
»
 

XY1                                                             @  calcul des cumuls Xj(0) et Yj(0) pour chaque type d'onde

 «
     .
X0 AM VIJ PH - COS * + 'X0' STO          @ AM est l'amplitude et PH la phase passées en paramètres. VIJ est
Y0 AM VIJ PH - SIN * + 'Y0' STO            @       fonction de l'heure.   X0 =  Xj(0)
»                                                                  @ Y0 = Yj(0)
 

XY2                                                            @  calcul des cumuls Xj(24) et Yj(24) pour chaque type d'onde.

 «
X24 AM VIJ PH - COS * + 'X24' STO     @ AM est l'amplitude et PH la phase passées en paramètres. VIJ est
Y24 AM VIJ PH - SIN * + 'Y24' STO      @     fonction de l'heure.   X24 =  Xj(24)
»                                                                 @ Y24 = Yj(24)
 

MODARG

 « R®C DUP ABS SWAP                         @ renvoie module et argument du nbre complexe
ARG

»
 

CORRAG                                                  @ corrige l’angle V pour qu’il entre dans l’intervalle –180 + 180 °

 « WHILE 'V>180' REPEAT 'V' 360 STO- END
  WHILE 'V<-180' REPEAT 'V' 360 STO+ END
»

APN                                                           @ calcul de l'heure précise de la marée par la méthode des
                                                                   @ approximations de Newton.

«
Z8 'T' STO                                                  @ heure approchée :de Z8 ds T
'T' 24 STO/                                                 @ temps en jours
0 'Z7' STO                                                  @ Z7 = cumul des dti pour vérifier la convergence.
T F * D + 'L' STO                                      @   dans L
 

T U * Q + 'M' STO                                @   dans M
T Z3 * Z1 + 'O' STO                              @   dans O
T G * E + 'V' STO                                 @   dans V
T W * R + 'X' STO                                @   dans X
T Z4 * Z2 + 'Y' STO                              @   dans Y

0.00138 'H' STO                                  @  2 mn dans H pour init

WHILE 'ABS(Z7)<=0.25 AND ABS(H)>=0.00069'
REPEAT
V SIN L *
X SIN M * 2 * +
Y SIN O * 4 * +
V COS L *
X COS M * 4 * +
Y COS O * 16 * + ‡ * 2 * ®NUM / NEG
'H' STO                                                          @   dans H

H 'Z7' STO+                                                  @ cumul
360 H * 'V' STO+
720 H * 'X' STO+                                         @ id. pour j=2
1440 H * 'Y' STO+                                       @ id. pour j=4
H 'T' STO+                                                   @ T = T +d t
END
 
 
 

IF 'ABS(Z7)>0.25' THEN "Divergence !" MSGBOX
                                                                   @ calcul impossible : cas de figure non traité par ce programme

ELSE
T 24 * DECAL + 'T' STO                         @ restitue l'heure locale (DECAL = décalage horaire
T DECAL - S + 'Z8' STO                         @ prépare le calcul suivant avec S = durée approchée de la marée.
CHT                                                         @ calcule la hauteur d'eau.
END
»

FMTTH                                                  @  formatte l’heure et la hauteur avec les unités .

« 1_m ®UNIT SWAP
  ®HMS 1_h ®UNIT ®STR
  SWAP +
»
 

CHT                                                        @ calcul de la hauteur d'eau à l'heure locale T.

 «
'T' DECAL STO-                                     @ soustraire le décalage hiver/été
'T' 24 STO/                                              @ temps en jour décimal.
T I * B + T K * C + COS *
T G * E + COS T F * D + * +
T W * R + COS T U * Q + * +
T Z4 * Z2 + COS T Z3 * Z1 + * +
Z0 +
'Y' STO                                                    @ Y = hauteur à l'instant T
 

'T' 24 STO*
'T' DECAL STO+                                    @ restitue l'heure locale
T                                                              @ sur la pile
Y                                                              @ hauteur sur la pile
»

AFFTH

 « ® T H                                                  @ affiche PORT DATE HEURE(T)  HAUTEUR (H)
  « PORT 6 FIX DTE
®STR 2 FIX "
le "
SWAP + + "
HEURE:"
T ®HMS '1_h' ®UNIT
+ + H '1_m' ®UNIT
"

Hauteur:" SWAP +
+ MSGBOX
  »
»
 
 
 

 

REPERTOIRE DES HARMONIQUES POUR HP48

BO

" BOHARM OBJ® "Boulogne *" 'PORT' STO "

BOHARM

{ 4.90 0.000 0 0.019 86 0.031 115 0.050 138 0.536 337 2.895 358 0.929 52 0.119 253 0.340 277 0.213 333 }

BR

" BRHARM OBJ® "Brest" 'PORT' STO "

BRHARM

{ 3.92 0.047 234 0.020 294 0.067 342 0.065 269 0.415 118 2.040 138 0.746 178 0.019 117 0.054 164 0.034 239 }

CA

"CAHARM OBJ® "Calais *" 'PORT' STO "

CAHARM

{ 4.00 0.081 219 0.025 80 0.050 160 0.026 81 0.441 352 2.459 15 0.779 69 0.090 283 0.254 309 0.150 6 }

CH

" CHHARM OBJ® "Cherbourg" 'PORT' STO "

CHHARM

{ 3.83 0.061 243 0.019 330 0.059 13 0.091 120 0.368 238 1.870 257 0.699 301 0.047 24 0.138 50 0.084 100 }

DI

" DIHARM OBJ® "Dieppe" 'PORT' STO "

DIHARM

{ 4.84 0.041 282 0.013 31 0.046 49 0.096 128 0.575 318 3.126 340 1.031 31 0.096 218 0.270 243 0.185 298 }

DK

" DKHARM OBJ® "Dunkerque " 'PORT' STO "

DKHARM

{ 3.24 .07 233 .032 111 .086 177 .033 12 .372 357 2.116 22 .627 75 .057 310.156 337 .087 35 }

DV

" DVHARM OBJ® "Dover *" 'PORT' STO "

DVHARM

{ 3.70 0.149 211 0.015 156 0.053 169 0.045 29 0.410 313 2.280 333 0.714 24 0.086 197 0.259 222 0.168 273 }

PO

" POHARM OBJ® "Portsmouth **" 'PORT' STO "

POHARM

{ 2.84 0.089 215 0.006 267 0.026 344 0.087 111 0.285 303 1.429 326 0.441 11 0.070 339 0.202 13 0.136 68 }

SH

" SHHARM OBJ® "Shoreham" 'PORT' STO "

SHHARM

{ 3.36 0.000 0 0.015 0 0.037 357 0.055 97 0.491 303 2.124 322 0.655 8 0.027 296 0.046 290 0.034 353 }

SO

" SOHARM OBJ® "Southampton ***" 'PORT' STO "

SOHARM

{ 2.87 0.029 133 0.009 323 0.031 342 0.089 116 0.265 303 1.379 328 0.419 13 0.084 357 0.256 20 0.164 80 }